Chào các pro.autocad, mình gặp phải vấn đề là tìm giao tuyến giữa hai mặt cong trong autocad, mình mò mãi mà không tài nào tìm ra được cách cả. A, mà nhân đây xin hỏi 2 biến điều khiển surftab1 và surftab2 mang giá trị bao nhiêu thì mình có thể pedit thành B-spline nhỉ? mình thử mãi chỉ được 6 -7, nó có hiện thông báo, quá nhiều điểm control và segment 6, potay. Còn scale theo một chiều nữa, trong autoship thì có thể scale theo x hoặc y hoặc z, như trong cad thì thấy không có hỗ trợ bác pro nào có thể chỉ điểm thêm.

Để scale theo một chiều, đầu tiên make block, sau đó chỉnh tỉ lệ scale trong mục insert block.

để scale theo một chiều bạn phải tạo block trước sau đó quét đối tượng rồi dùng lệnh mo xuất hiện thuộc tính của đối tượng,sau đó có thể tùy chỉnh scale theo trục x,y,z.Vì cái này làm khá đơn giản nên tui không post hình :D
chúc bạn thành công!

bạn copy đoạn mã này vào file notepad , rôi lưu file dưới dạng đuôi .lsp
- Khởi động AutoCAD
- chọn tool - load application - chọn đường dẫn đến file
- nhấn Load
Tại dòng command : giaotuyen

";---------------------------------------------------------------------
;- Command GiaoTuyen ()
;- Creates a points at the the intersection of a line and a plane
;- The user selects the three points defining the plane and the
;- two points defining the line.


(defun c:Giaotuyen ()
;-- Get the plane points
(setq pp1 (getpoint "\nSelect the 1st point on the plane: "))
(setq pp2 (getpoint "\nSelect the 2nd point on the plane: "))
(setq pp3 (getpoint "\nSelect the 3rd point on the plane: "))

;-- Get the line points
(setq lp1 (getpoint "\nSelect the 1st point on the line: "))
(setq lp2 (getpoint "\nSelect the 2nd point on the line: "))

;-- Find the intersection
(setq int_pt (line_plane_int (list pp1 pp2 pp3) (list lp1 lp2) ))

;-- Draw the intersection point
(command "_point" (car int_pt))
)


;---------------------------------------------------------------------
;- Function LINE_PLANE_INT (PLANE_PTS LINE_PTS)
;- Finds the intersection of a line and a plane
;-
;- Arguments: Point list of the form
;- ( (p1 p2 p3) (l1 l2) )
;- PLANE_PTS p1->p3 is the points list defining the plane
;- LINE_PTS l1 and l2 are the points defining the line
;-
;- RETURNS the intersection point and 'T' if the point is inside
;- the triangle p1->p2->p3, else nil of the form
;- ( (x y z) T ) or ( (x y z) nil )
;-
;- Copyright 2006 Jeff Winship. All rights reserved.
;------------------------------------------------------------7/05/2006
(defun line_plane_int (ppts lpts / xa ya za xb yb zb x0 y0 z0 x1 y1 z1 x2 y2 z2 mat1 xc yc zc w u v pt t1 t2 t3)

(setq xa (car (nth 0 lpts)))
(setq ya (cadr (nth 0 lpts)))
(setq za (caddr (nth 0 lpts)))

(setq xb (car (nth 1 lpts)))
(setq yb (cadr (nth 1 lpts)))
(setq zb (caddr (nth 1 lpts)))

(setq x0 (car (nth 0 ppts)))
(setq y0 (cadr (nth 0 ppts)))
(setq z0 (caddr (nth 0 ppts)))

(setq x1 (car (nth 1 ppts)))
(setq y1 (cadr (nth 1 ppts)))
(setq z1 (caddr (nth 1 ppts)))

(setq x2 (car (nth 2 ppts)))
(setq y2 (cadr (nth 2 ppts)))
(setq z2 (caddr (nth 2 ppts)))

;--- Load the matrix to invert
(setq mat1 (list
(list (- xa xb) (- x1 x0) (- x2 x0))
(list (- ya yb) (- y1 y0) (- y2 y0))
(list (- za zb) (- z1 z0) (- z2 z0))
))

;--- Invert the matrix
(setq mat1 (matrix_inverse3 mat1))

;--- Solve for the column variables
(setq xc (- xa x0))
(setq yc (- ya y0))
(setq zc (- za z0))

;--- Solve for the parametric variables (w is substitued for t)
(setq w (+
(* xc (car (nth 0 mat1)))
(* yc (cadr (nth 0 mat1)))
(* zc (caddr (nth 0 mat1)))
))
(setq u (+
(* xc (car (nth 1 mat1)))
(* yc (cadr (nth 1 mat1)))
(* zc (caddr (nth 1 mat1)))
))
(setq v (+
(* xc (car (nth 2 mat1)))
(* yc (cadr (nth 2 mat1)))
(* zc (caddr (nth 2 mat1)))
))

;--- Solve for the intersection point
(setq pt (list
(+ xa (* w (- xb xa)))
(+ ya (* w (- yb ya)))
(+ za (* w (- zb za)))
))
;--- Determine if the intersection point is inside the triangle
(setq t1 (and (>= u 0.0) (<= u 1.0)))
(setq t2 (and (>= v 0.0) (<= v 1.0)))
(setq t3 (<= (+ u v) 1.0))

;--- Add the condition result to the point list
(setq pt (list pt (and t1 t2 t3)))
)


;---------------------------------------------------------------------
;- Function MATRIX_INVERSE3 (MLIST)
;- Finds the inverse of a 3x3 matrix
;- Arguments: Matrix list of the form
;- ( (r1c1 r1c2 r1c3) (r2c1 r2c2 r2c3) ....)
;-
;- Copyright 2006 Jeff Winship. All rights reserved.
;------------------------------------------------------------7/05/2006
(defun matrix_inverse3 (mlist / mlist det row1 row2 row3 a11 a12 a13 a21 a22 a23 a31 a32 a33 matrix)
(setq row1 (nth 0 mlist))
(setq row2 (nth 1 mlist))
(setq row3 (nth 2 mlist))
(setq a11 (nth 0 row1)
a12 (nth 1 row1)
a13 (nth 2 row1)
)
(setq a21 (nth 0 row2)
a22 (nth 1 row2)
a23 (nth 2 row2)
)
(setq a31 (nth 0 row3)
a32 (nth 1 row3)
a33 (nth 2 row3)
)

;--- Find the determinant ----
(setq det (matrix_det3 mlist))

;--- Use the row variables to define the new inverse matrix
(setq row1 (list
(/ (- (* a22 a33) (* a32 a23)) det)
(/ (- (* a13 a32) (* a33 a12)) det)
(/ (- (* a12 a23) (* a22 a13)) det)
))
(setq row2 (list
(/ (- (* a23 a31) (* a33 a21)) det)
(/ (- (* a11 a33) (* a31 a13)) det)
(/ (- (* a13 a21) (* a23 a11)) det)
))
(setq row3 (list
(/ (- (* a21 a32) (* a31 a22)) det)
(/ (- (* a12 a31) (* a32 a11)) det)
(/ (- (* a11 a22) (* a21 a12)) det)
))

;--- Return the matrix
(setq matrix (list row1 row2 row3))
)

;---------------------------------------------------------------------
;- Function MATRIX_DET3 (MLIST)
;- Calculates and returns the determinate of a 3x3 matrix
;- Arguments: Matrix list of the form
;- ( (r1c1 r1c2 r1c3) (r2c1 r2c2 r2c3) ....)
;-
;- Copyright 2008 Jeff Winship. All rights reserved.
;------------------------------------------------------------7/05/2006
(defun matrix_det3 (mlist / mlist row1 row2 row3 a1 a2 a3 b1 b2 b3 c1 c2 c3 det)
(setq row1 (nth 0 mlist))
(setq row2 (nth 1 mlist))
(setq row3 (nth 2 mlist))
(setq a1 (nth 0 row1)
a2 (nth 1 row1)
a3 (nth 2 row1)
)
(setq b1 (nth 0 row2)
b2 (nth 1 row2)
b3 (nth 2 row2)
)
(setq c1 (nth 0 row3)
c2 (nth 1 row3)
c3 (nth 2 row3)
)
;--- Do the calcs ----
(setq det (+
(* a1 b2 c3)
(- (* a1 b3 c2))
(- (* a2 b1 c3))
(* a2 b3 c1)
(* a3 b1 c2)
(- (* a3 b2 c1))
))
(setq det (float det))
)
(alert "Bui Cong Loc - Nha Trang University")"